Nagios 利用NSClient++的check_nrpe方式使用自定義腳本監控windows

如果在windows下用nagios實現資源監控，則需要用到NSClient++，這里分享一個NSClient++自定義腳本，有需要的朋友參考下。

實現：
windows環境下nagios監控程序的進程關閉后自動啟動。

首先，編輯NSClient配置文件NSC.ini，去掉以下幾行前面的“；”號（去掉注釋，使其生效）：
 

NRPEListener.dll
script_dir=scripts\
CheckExternalScripts.dll

在NSClient安裝目錄下的scripts文件夾下，新建一個check_run.bat批處理文件，如下：
 

代碼示例:

@echo off
tasklist |find "%1" >NUL
IF ERRORLEVEL 1 GOTO err
IF ERRORLEVEL 0 GOTO ok

:err
echo CRITICAL: Process does not exist
start "" "%2\%1"
exit /B 2

:ok
echo OK: The process of normal
exit /B 0

在NSC.ini文件中[External Scripts]下面添加如下行：
 

代碼示例:

check_run=scripts\check_run.bat   Process.exe    pro/path

重啟NSClient服務。

在nagios監控主機中，添加如下服務信息：
 

代碼示例:

define service{
        use                   generic-service
        host_name             servername
        service_description   check_processname
        check_command         check_nrpe!check_run
        }
 

重啟nagios服務，使配置生效。

監控windows上tcp連接數：

@echo off

netstat -an | find /C "TCP" > d:\tcpcount.txt

for /f %%i in (d:\tcpcount.txt) do (

set tcpc=%%i

)

if %tcpc% GTR 5000 ( 

echo  criting: tcp connection count %tcpc%

exit /B 2

)

if not %tcpc% GTR 5000 if  %tcpc% GTR 3000 (

echo  warning: tcp connection count %tcpc%

exit /B 1

)  

if not %tcpc% GTR 3000 ( 

echo  ok: tcp connection count %tcpc%

exit /B 0

)

監控windows文件中關鍵詞出現次數：

@echo off

set FILE=D:\dcsLogs\logback\pxylist\common\common-all.log

set ERROR=OutOfMemoryError

for /f "delims=" %%a in ('type %FILE%^|find /C "%ERROR%"') do set myvar=%%a

if %myvar% NEQ 0 ( 

echo CRITICAL:error count %myvar%

exit /B 2

)

if %myvar% EQU 0 ( 

echo OK:error count %myvar%

exit /B 0

)

監控windows文件中關鍵詞出現次數（增加判斷文件是否存在）：

@echo off

set FILE=D:\dcsLogs\logback\pxylist\common\common-all.log

set ERROR=OutOfMemoryError

setlocal EnableDelayedExpansion

if EXIST %FILE% (

for /f "delims=" %%a in ('type %FILE%^|find /C /I "%ERROR%"') do set myvar=%%a

if !myvar! NEQ 0 ( 

echo CRITICAL:error count !myvar!-OutOfMemory,Please restart pxylist

exit /B 2

)else ( 

echo OK:error count !myvar!

exit /B 0

)

)else (

echo CRITICAL:%FILE% is not exist

exit /B 2

)

監控windows上多個進程名各自是否只跑了一個進程：

@echo off

SET PROCESS1=telegraph.exe
SET PROCESS2=WindowsApplication1.exe

for /f "delims=" %%a in ('tasklist /v /nh /fo csv /fi "IMAGENAME eq %PROCESS1%"^|find /c "%PROCESS1%"') do set myvar=%%a

if %myvar% NEQ 1 (
echo CRITICAL: %PROCESS1% running %myvar% process
exit /B 2
)

for /f "delims=" %%a in ('tasklist /v /nh /fo csv /fi "IMAGENAME eq %PROCESS2%"^|find /c "%PROCESS2%"') do set myvar=%%a

if %myvar% NEQ 1 (
echo CRITICAL: %PROCESS2% running %myvar% process
exit /B 2
)

for /f "delims=" %%a in ('tasklist /nh ^|findstr "%PROCESS1% %PROCESS2%"^|find /v /c "::"') do set myvar=%%a

if %myvar% EQU 2 (
echo OK: %PROCESS1% %PROCESS2% all running 1 process
exit /B 0
)

----------------------------------------------------------------------------------

Exit

退出當前批處理腳本或 Cmd.exe 程序（即，命令解釋程序）并返回到曾啟動 Cmd.exe 的程序或返回到“程序管理器”。

語法

exit [/b] [ExitCode]

參數

• /b

• 退出當前批處理腳本。

• ExitCode

• 指定數字編號。

• /?

• 在命令提示符顯示幫助。

注釋

• 如果在批處理腳本之外使用 /b，就會退出 Cmd.exe。

• 如果使用 /b，Cmd.exe 將 ERRORLEVEL 設置為指定的 ExitCode。如果退出 Cmd.exe，Cmd.exe 則使用指定的 ExitCode 設置進程退出代碼。

關于 exit /b [ExitCode]的詳解：

功能： Cmd.exe 將 ERRORLEVEL 設置為指定的 ExitCode。如果退出 Cmd.exe，Cmd.exe 則使用指定的 ExitCode 設置進程退出代碼。

示例：leo.bat。

然后，我們在 CMD 命令提示符下進行操作：

執行：leo.bat

執行：Echo %errorlevel%

30194447