.版本 2
.DLL命令 CoInitialize, 整數型, "ole32.dll", , 公開, 初始化對象開始
  .參數 pvReserved, 整數型, , 0
.DLL命令 CoUninitialize, 整數型, "ole32.dll", , 公開, 初始化對象結束
.DLL命令 ShellExecute, 整數型, "shell32.dll", "ShellExecuteA"
  .參數 hwnd, 整數型, , 指定一個窗口的句柄，有時候，windows程序有必要在創建自己的主窗口前顯示一個消息框
  .參數 lpOperation, 文本型, , 指定字串“open”來打開lpFlie文檔，或指定“Print”來打印它
  .參數 lpFile, 文本型, , 想用關聯程序打印或打開一個程序名或文件名
  .參數 lpParameters, 文本型, , 如lpszFlie是可執行文件，則這個字串包含傳遞給執行程序的參數
  .參數 lpDirectory, 文本型, , 想使用的完整路徑
  .參數 nShowCmd, 整數型, , 定義了如何顯示啟動程序的常數值。參考ShowWindow函數的nCmdShow參數

.版本 2
.數據類型 _kuwoSong, 公開
  .成員 music_id, 文本型
  .成員 name, 文本型
  .成員 song_url, 文本型
  .成員 singer, 文本型
  .成員 mp3size, 文本型
  .成員 path, 文本型
  .成員 mp3path, 文本型
  .成員 aacpath, 文本型
  .成員 wmadl, 文本型
  .成員 mp3dl, 文本型
  .成員 aacdl, 文本型
  .成員 lyric, 文本型
  .成員 lyric_zz, 文本型

.版本 2
.支持庫 internet
.支持庫 EThread
.支持庫 iext
.程序集 窗口程序集_窗口1
.程序集變量 kuwoSong, _kuwoSong
.程序集變量 開始解析, 邏輯型
.子程序 __啟動窗口_創建完畢
.子程序 GetSongInfo, 邏輯型
.參數 music_id, 文本型
.局部變量 bin, 字節集
.局部變量 str, 文本型
bin ＝ HTTP讀文件 (“http://www.kuwo.cn/webmusic/st/getMuiseByRid?rid=MUSIC_” ＋ music_id ＋ “&flag=3&r=” ＋ Random ())
str ＝ 到文本 (CCharset (bin))
kuwoSong.name ＝ GetStr (str, “<name>”, “</name>”)
kuwoSong.path ＝ GetStr (str, “<path>”, “</path>”)
kuwoSong.wmadl ＝ GetStr (str, “<wmadl>”, “</wmadl>”)
kuwoSong.mp3dl ＝ GetStr (str, “<mp3dl>”, “</mp3dl>”)
kuwoSong.aacdl ＝ GetStr (str, “<aacdl>”, “</aacdl>”)
kuwoSong.lyric ＝ GetStr (str, “<lyric>”, “</lyric>”)
kuwoSong.singer ＝ GetStr (str, “<singer>”, “</singer>”)
kuwoSong.mp3size ＝ GetStr (str, “<mp3size>”, “</mp3size>”)
kuwoSong.mp3path ＝ GetStr (str, “<mp3path>”, “</mp3path>”)
kuwoSong.aacpath ＝ GetStr (str, “<aacpath>”, “</aacpath>”)
kuwoSong.music_id ＝ GetStr (str, “<music_id>”, “</music_id>”)
kuwoSong.song_url ＝ GetStr (str, “<song_url>”, “</song_url>”)
kuwoSong.lyric_zz ＝ GetStr (str, “<lyric_zz>”, “</lyric_zz>”)
.如果 (kuwoSong.music_id ＝ “”)
  返回 (假)
.否則
  返回 (真)
.如果結束
.子程序 Random, 文本型, 公開
.局部變量 VBScript, 對象
.局部變量 值, 雙精度小數型
.局部變量 文本值, 文本型
VBScript.創建 (“ScriptControl”, )
VBScript.寫屬性 (“Language”, “JScript”)
VBScript.數值方法 (“ExecuteStatement”, “function random(){return Math.random()}”)
值 ＝ VBScript.通用方法 (“Run”, “random”, ).取數值 ()
文本值 ＝ 到文本 (值)
返回 (文本值)
.子程序 CCharset, 字節集, 公開, 改變編碼
.參數 待轉換數據, 字節集
.參數 轉換前編碼, 文本型, 可空, 默認UTF-8,utf-8；unicode；GBK 等
.參數 轉換后編碼, 文本型, 可空, 默認GBK,utf-8；unicode；GBK 等
.參數 轉換后數據開始位置, 整數型, 可空, 位置從0開始。unicode編碼標識占2個字節，utf-8編碼標識占3個字節
.局部變量 文本, 文本型
.局部變量 變體型, 變體型
.局部變量 this, 對象
.局部變量 返回值, 字節集
.如果真 (是否為空 (轉換前編碼) ＝ 真)
  轉換前編碼 ＝ “UTF-8”
.如果真結束
.如果真 (是否為空 (轉換后編碼) ＝ 真)
  轉換后編碼 ＝ “GBK”
.如果真結束
this.創建 (“Adodb.Stream”, )
this.寫屬性 (“Type”, 1)
this.方法 (“Open”, )
變體型.創建數組 (#字節型, 取字節集長度 (待轉換數據))
變體型.賦值 (待轉換數據, )
this.方法 (“Write”, 變體型)
this.寫屬性 (“Position”, 0)
this.寫屬性 (“Type”, 2)
this.寫屬性 (“Charset”, 轉換前編碼)
文本 ＝ this.文本方法 (“ReadText”, -1)
this.方法 (“Close”, )
this.方法 (“Open”, )
this.寫屬性 (“Charset”, 轉換后編碼)
this.方法 (“WriteText”, 文本, )
this.寫屬性 (“Position”, 0)
this.寫屬性 (“Type”, 1)
.如果真 (是否為空 (轉換后數據開始位置) ＝ 假)
  this.寫屬性 (“Position”, 轉換后數據開始位置)
.如果真結束
變體型 ＝ this.通用方法 (“Read”, -1)
返回值 ＝ 變體型.取字節集 ()
返回 (返回值)
.子程序 GetStr, 文本型, 公開
.參數 內容, 文本型
.參數 頭, 文本型
.參數 尾, 文本型
.參數 返回數組, 文本型, 可空 數組
.局部變量 開始, 整數型
.局部變量 結束, 整數型
.局部變量 長度, 整數型
.局部變量 結果內容, 文本型, , "0"
.判斷循環首 (尋找文本 (內容, 頭, 開始, 真) ≠ -1)
  開始 ＝ 尋找文本 (內容, 頭, 開始, 真) ＋ 取文本長度 (頭)
  結束 ＝ 尋找文本 (內容, 尾, 開始, 真)
  .如果真 (開始 ＝ -1 或 結束 ＝ -1)
    到循環尾 ()
  .如果真結束
  長度 ＝ 結束 － 開始
  加入成員 (結果內容, 取文本中間 (內容, 開始, 長度))
.判斷循環尾 ()
返回數組 ＝ 結果內容
.如果 (取數組成員數 (返回數組) ＞ 0)
  返回 (返回數組 [1])
.否則
  返回 (“”)
.如果結束
.子程序 _按鈕1_被單擊
.如果 (開始解析)
  信息框 (“請稍等片刻，上次操作還在處理中......”, 0, “提示”)
.否則
  啟動線程 (&子程序2, , )
.如果結束
.子程序 子程序2
.局部變量 music_id, 文本型
CoInitialize (0)
開始解析 ＝ 真
kuwoSong.music_id ＝ “”
超級列表框1.置標題 (0, 1, “”)
超級列表框1.置標題 (1, 1, “”)
超級列表框1.置標題 (2, 1, “”)
超級列表框1.置標題 (3, 1, “”)
超級列表框1.置標題 (4, 1, “”)
超級列表框1.置標題 (5, 1, “”)
music_id ＝ GetStr (編輯框1.內容 ＋ “/”, “/yinyue/”, “/”)
.如果 (GetSongInfo (music_id))
  加入列表框 ()
.否則
  信息框 (“獲取失敗，請檢查地址是否正確或工具已失效......”, 0, “提示”)
.如果結束
開始解析 ＝ 假
CoUninitialize ()
.子程序 加入列表框
超級列表框1.置標題 (0, 1, kuwoSong.name)
超級列表框1.置標題 (1, 1, kuwoSong.singer)
超級列表框1.置標題 (2, 1, kuwoSong.mp3size)
超級列表框1.置標題 (3, 1, “http://” ＋ kuwoSong.mp3dl ＋ kuwoSong.mp3path)
.如果真 (kuwoSong.wmadl ≠ “”)
  超級列表框1.置標題 (4, 1, “http://” ＋ kuwoSong.wmadl ＋ kuwoSong.path)
.如果真結束
.如果真 (kuwoSong.aacdl ≠ “”)
  超級列表框1.置標題 (5, 1, “http://” ＋ kuwoSong.aacdl ＋ kuwoSong.aacpath)
.如果真結束
.子程序 _超級列表框1_被雙擊, 邏輯型
.參數 橫向位置, 整數型
.參數 縱向位置, 整數型
.參數 功能鍵狀態, 整數型
.局部變量 下載地址, 文本型
.如果真 (超級列表框1.現行選中項 ＝ 3 或 超級列表框1.現行選中項 ＝ 4 或 超級列表框1.現行選中項 ＝ 5)
  下載地址 ＝ 超級列表框1.取標題 (超級列表框1.現行選中項, 1)
  .如果真 (取文本長度 (下載地址) ＞ 10)
    ShellExecute (0, “open”, 下載地址, “”, “”, 1)
    返回 ()
  .如果真結束
.如果真結束