Android Studio Gradle第三依賴統一管理怎么實現

這篇文章主要介紹“Android Studio Gradle第三依賴統一管理怎么實現”的相關知識，小編通過實際案例向大家展示操作過程，操作方法簡單快捷，實用性強，希望這篇“Android Studio Gradle第三依賴統一管理怎么實現”文章能幫助大家解決問題。

一、AndroidStudio Gradle第三依賴統一管理
二、AndroidStudio Gradle基于友盟的多渠道打包
三、AndroidStudio安全管理簽名文件keystroe和簽名密碼

這三篇文章很好的講解了gradle的在打包和項目依賴管理的優點，大家可以參考一下，來提高自己的開發效率，增強簽名文件的安全性。

在很多時候我們使用AndroidStudio開發安卓App的時候都會引入第三方的庫，在一個project下我們可以有很多的module，每一個module就是一個app，但是每個module在進行第依賴第三方的時候，有可能依賴第三方的版本不同，記住每次使用的版本號也不太可能，所以統一管理第三方依賴就尤其的重要。

我們可以將依賴的第三方集中放入到一個gradle中，然后在需要使用的的module中將其引入即可，這樣很方便的進行的了不同版本的管理了。

首先我們在project下新建一個叫“config.gradle”的文件（名字隨便起），然后將要的所有第三方依賴庫進行配置。

ext {
 
 android = [
   compileSdkVersion: 23,
   buildToolsVersion: "24.0.2",
   minSdkVersion : 15,
   targetSdkVersion : 23,
   versionCode  : 1,
   versionName  : "1.0"
 ]

 dependVersion = [
   support: "23.4.0"
 ]

 dependencies = [
   // ------------- Android -------------
   supportV4   : "com.android.support:support-v4:${dependVersion.support}",
   appcompatV7   : "com.android.support:appcompat-v7:${dependVersion.support}",
   design    : "com.android.support:design:${dependVersion.support}",
   junit    : "junit:junit:4.12",
   //------------- 測試 -------------
   espresso    : "com.android.support.test.espresso:espresso-core:2.2.2",

   // ------------- 網絡請求 -------------
   okhttp    : 'com.squareup.okhttp3:okhttp:3.3.1',
   retrofit    : 'com.squareup.retrofit2:retrofit:2.1.0',

   // ------------- 圖片加載 -------------
   fresco    : 'com.facebook.fresco:fresco:0.11.0',
   animatedGif   : 'com.facebook.fresco:animated-gif:0.12.0',
   picasso    : 'com.squareup.picasso:picasso:2.5.2',
   photoView   : 'com.github.chrisbanes:PhotoView:1.3.1',

   // ------------- RxAndroid -------------
   rxAndroid   : 'io.reactivex:rxandroid:1.2.1',
   rxJava    : 'io.reactivex:rxjava:1.2.2',

   // ------------- json解析 -------------
   fastJson    : 'com.alibaba:fastjson:1.1.54.android',
   gson     : 'com.google.code.gson:gson:2.8.0',

   // ------------- log打印工具 -------------
   logger    : 'com.orhanobut:logger:1.15',

   greendao    : 'org.greenrobot:greendao:3.2.0',

   // ------------- ButterKnife -------------
   butterknife   : 'com.jakewharton:butterknife:8.4.0',
   butterknifeCompiler : 'com.jakewharton:butterknife-compiler:8.4.0',

   // ------------- LeakCanary -------------
   leakcanaryAndroid : 'com.squareup.leakcanary:leakcanary-android:1.5',
   leakcanaryAndroidNoOp: 'com.squareup.leakcanary:leakcanary-android-no-op:1.5',
 ]
}

這樣我們就配置好了所有的依賴庫了，接下來就是要需要的依賴庫引入到我們的module中了。
1、在我們的project中的build.gradle中添加

apply from: "config.gradle"

2、在我們的module的build.gradle中引入
這是引入之前的gradle

apply plugin: 'com.android.application'
android {
 compileSdkVersion 23
 buildToolsVersion "24.0.2"

 defaultConfig {
  applicationId "com.bandeng.bandeng"
  minSdkVersion 15
  targetSdkVersion 23
  versionCode 1
  versionName "1.0"
  testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
 }
 buildTypes {
  release {
   minifyEnabled false
   proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
  }
 }
}
dependencies {
	compile fileTree(dir: 'libs', include: ['*.jar'])
 androidTestCompile("com.android.support.test.espresso:espresso-core:2.2.2", {
  exclude group: 'com.android.support', module: 'support-annotations'
 })
 compile "com.android.support:appcompat-v7:23.4.0"
 testCompile "junit:junit:4.12"
 compile "com.android.support:design:23.4.0"
}

改造之后的gradle

apply plugin: 'com.android.application'

android {
 compileSdkVersion rootProject.ext.android.compileSdkVersion
 buildToolsVersion rootProject.ext.android.buildToolsVersion

 defaultConfig {
  applicationId "com.bandeng.bandeng"
  minSdkVersion rootProject.ext.android.minSdkVersion
  targetSdkVersion rootProject.ext.android.targetSdkVersion
  versionCode rootProject.ext.android.versionCode
  versionName rootProject.ext.android.versionName
  testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
 }
 buildTypes {
  release {
   minifyEnabled false
   proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
  }
 }
}
dependencies {
 compile fileTree(dir: 'libs', include: ['*.jar'])
 androidTestCompile(rootProject.ext.dependencies.espresso, {
  exclude group: 'com.android.support', module: 'support-annotations'
 })
 compile rootProject.ext.dependencies.appcompatV7
 testCompile rootProject.ext.dependencies.junit
 compile rootProject.ext.dependencies.design
 // 網絡請求
 compile rootProject.ext.dependencies.okhttp
 compile rootProject.ext.dependencies.retrofit
 // 圖片加載
 compile rootProject.ext.dependencies.picasso
	// RxJava
 compile rootProject.ext.dependencies.rxAndroid
 compile rootProject.ext.dependencies.rxJava
 // json解析
 compile rootProject.ext.dependencies.gson
 // log打印工具
 compile rootProject.ext.dependencies.logger
}

這樣是不是很方便的管理依賴的第三方了。

關于“Android Studio Gradle第三依賴統一管理怎么實現”的內容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業相關的知識，可以關注億速云行業資訊頻道，小編每天都會為大家更新不同的知識點。