Oracle中通過函數實現二、八、十、十六進制任意轉換

說明：本文主要參考于： http://www.eygle.com/archives/2004/06/oracle_howto_convert.html

一、先創建兩個基本的進制轉換函數：

    1.其他進制（2,8,16）轉換為十進制

    Create Or Replace Function To_Dec(p_Str       In Varchar2,    --要轉換的數字（2,8,16進制）
                                      p_From_Base In Number Default 16)    --轉換前的進制
      Return Number Is
      i_Num Number Default 0;
      i_Hex Varchar2(16) Default '0123456789ABCDEF';
    Begin
      For i In 1 .. Length(p_Str) Loop
        i_Num := i_Num * p_From_Base + Instr(i_Hex, Upper(Substr(p_Str, i, 1))) - 1;
      End Loop;
      Return i_Num;
    End To_Dec;

    2.十進制轉換為其它進制（2,8,16）

    Create Or Replace Function To_Base(p_Dec In Number,    --要轉換的數字（10進制）
                                       p_Base In Number)   --轉換后的進制
      Return Varchar2 Is
      i_Str Varchar2(255) Default Null;
      i_Num Number Default p_Dec;
      i_Hex Varchar2(16) Default '0123456789ABCDEF';
    Begin
      If Trunc(p_Dec) <> p_Dec Or p_Dec < 0 Then
        Raise Program_Error;
      End If;
      Loop
        i_Str := Substr(i_Hex, Mod(i_Num, p_Base) + 1, 1) || i_Str;
        i_Num := Trunc(i_Num / p_Base);
        Exit When i_Num = 0;
      End Loop;
      Return i_Str;
    End To_Base;

二、通過上面兩個函數，可以將10進制作為轉換的中間橋梁。在進行任意進制轉換時，都可以先將要轉換的進制轉為10進         制，然后再通過10進制轉換為別的進制。 通過下面函數來實現：

    Create Or Replace Function Bodh_Convert(p_Str  In Varchar2, --要轉換的數字（2,8,10,16進制）
                                            p_From Number,      --轉換前的進制
                                            p_To   Number)      --轉換后的進制
      Return Varchar2 Is
      v_Temp Number Default 0;
      v_Num  Varchar2(128) Default Null;
    Begin
      If p_From = 2 Then
        If p_To = 8 Then
          v_Temp := To_Dec(p_Str, p_From);
          v_Num  := To_Base(v_Temp, p_To);
        Elsif p_To = 10 Then
          v_Num := To_Dec(p_Str, p_From);
        Elsif p_To = 16 Then
          v_Temp := To_Dec(p_Str, p_From);
          v_Num  := To_Base(v_Temp, p_To);
        End If;
      Elsif p_From = 8 Then
        If p_To = 2 Then
          v_Temp := To_Dec(p_Str, p_From);
          v_Num  := To_Base(v_Temp, p_To);
        Elsif p_To = 10 Then
          v_Num := To_Dec(p_Str, p_From);
        Elsif p_To = 16 Then
          v_Temp := To_Dec(p_Str, p_From);
          v_Num  := To_Base(v_Temp, p_To);
        End If;
      Elsif p_From = 10 Then
        If p_To = 2 Then
          v_Num := To_Base(To_Number(p_Str), p_To);
        Elsif p_To = 8 Then
          v_Num := To_Base(To_Number(p_Str), p_To);
        Elsif p_To = 16 Then
          v_Num := To_Base(To_Number(p_Str), p_To);
        End If;
      Elsif p_From = 16 Then
        If p_To = 2 Then
          v_Temp := To_Dec(p_Str, p_From);
          v_Num  := To_Base(v_Temp, p_To);
        Elsif p_To = 8 Then
          v_Temp := To_Dec(p_Str, p_From);
          v_Num  := To_Base(v_Temp, p_To);
        Elsif p_To = 10 Then
          v_Num := To_Dec(p_Str, p_From);
        End If;
      End If;
      Return v_Num;
    Exception
      When Others Then
        Dbms_Output.Put_Line('請輸入正確的參數');
    End Bodh_Convert;

三、示例：

    SQL> select bodh_convert('1111',2,8) from dual;    --2進制轉8進制
     
    BODH_CONVERT('1111',2,8)
    --------------------------------------------------------------------------------
    17
     
    SQL> select bodh_convert('1111',2,10) from dual;    --2進制轉10進制
     
    BODH_CONVERT('1111',2,10)
    --------------------------------------------------------------------------------
    15
     
    SQL> select bodh_convert('1111',2,16) from dual;    --2進制轉16進制
     
    BODH_CONVERT('1111',2,16)
    --------------------------------------------------------------------------------
    F