.版本 2
.DLL命令 GetBitmapBits, 整數型, "gdi32", "GetBitmapBits"
  .參數 hBitmap, 整數型
  .參數 dwCount, 整數型
  .參數 lpBits, 整數型

.版本 2
.程序集 透明編輯框_EX, 編輯框_Ex
.程序集變量 img, 整數型
.程序集變量 類_左邊, 整數型
.程序集變量 類_頂邊, 整數型
.子程序 _初始化, , , 當基于本類的對象被創建后，此方法會被自動調用
.子程序 _銷毀, , , 當基于本類的對象被銷毀前，此方法會被自動調用
.子程序 _OnObjProc, 整數型, 公開, 虛函數,組件消息.返回值:0放行，1攔截。在 _ObjProc 之前被調用.
.參數 hWnd, 整數型
.參數 hObj, 整數型
.參數 uMsg, 整數型
.參數 wParam, 整數型
.參數 lParam, 整數型
.判斷開始 (uMsg ＝ #事件_創建)
  img ＝ 圖像_復制部分 (取EX指針 (窗口_取指針 (類_取成員值 (取指針 (), 2))), 左邊 () ＋ 10 ＋ 類_左邊, 頂邊 () ＋ 9 ＋ 類_頂邊, 寬度 (), 高度 ())
.判斷 (uMsg ＝ #事件_銷毀)
  圖像_銷毀 (img)
.默認
.判斷結束
返回 (0)
.子程序 _計算客戶區_編輯框, , 公開
.參數 客戶區矩形, RectF, 參考 可空, 修改本參數將影響文本所在矩形
OFFSETRCF (5, 0, -10, -6, 客戶區矩形)
.子程序 _繪制背景_編輯框, , 公開
.參數 exp, Exs_PaintStruct
.局部變量 m_文本格式, 整數型
.局部變量 m_字體指針, 整數型
.局部變量 Yw, 整數型
圖形_平滑模式 (exp.mGraphics, #平滑模式_最佳質量)
圖形_繪圖 (exp.mGraphics, img)
.子程序 取EX指針, 整數型, , 句柄：窗口指針或組件句柄，返回PNG
.參數 句柄, 整數型
.參數 窗口只打印背景, 邏輯型, 可空
.局部變量 hBitmap, 整數型
.局部變量 Rc, RECT
.局部變量 length, 整數型
.局部變量 Bitmap, 整數型
.局部變量 BitData, BITMAPDATA
.局部變量 Image, 字節集
.如果 (組件_取成員值 (句柄, 4) ＝ 句柄) ' exdui和obj類的成員4都是窗口指針，相同則說明參數是窗口指針
  .如果 (窗口只打印背景)
    hBitmap ＝ 組件_取成員值 (句柄, 32) ' 背景位圖緩存
  .否則
    hBitmap ＝ 組件_取成員值 (句柄, 28) ' 窗口位圖
  .如果結束
  GetWindowRect (組件_取成員值 (句柄, 2), Rc)
.否則
  hBitmap ＝ 組件_取成員值 (句柄, 44)
  CopyMemory (指針到整數 (取指針_通用型 (Rc)), 類_取成員指針 (句柄, 53), 4 × 4) ' 53-56
.如果結束
length ＝ GetBitmapBits (hBitmap, 0, 0) ' 獲取長度
Bitmap ＝ 圖像_創建自像素格式 (Rc.right － Rc.left, Rc.bottom － Rc.top)
圖像_鎖定數據 (Bitmap, MakeRC (0, 0, Rc.right － Rc.left, Rc.bottom － Rc.top), 位或 (#圖像鎖定模式_讀, #圖像鎖定模式_寫), #像素格式_32bppPARGB, BitData)
GetBitmapBits (hBitmap, length, BitData.Scan0) ' 獲取拷貝位圖數據
圖像_解鎖數據 (Bitmap, BitData)
返回 (Bitmap)
.子程序 設置位置, , 公開
.參數 左邊, 整數型
.參數 頂邊, 整數型
類_左邊 ＝ 左邊
類_頂邊 ＝ 頂邊

.版本 2
.支持庫 exui
.程序集 程序集1
.程序集變量 Ex_hDll, 整數型
.程序集變量 MainWindow, Ex_DirectUI
.程序集變量 Mainhwnd, 整數型
.程序集變量 MSLabel, 標簽_Ex
.程序集變量 MSGroupBox, 分組框_Ex, , "4"
.程序集變量 MSEditBox, 透明編輯框_EX, , "4"
.程序集變量 GroupBoxHandle, 整數型, , "4"
.程序集變量 MSPictureFrame, 圖片框_Ex, , "4"
.程序集變量 MSGraphicButton, 圖形按鈕_Ex
.子程序 _啟動子程序, 整數型, , 本子程序在程序啟動后最先執行
Ex_hDll ＝ _LoadLibrary (取指針_字節集型 (#Dll_ExduiDll), 0, 0)
Mainhwnd ＝ 窗口_創建 (, “cookie分析”, , , 980, 620, )
全局_初始化 (Ex_hDll, 真, #主題包_Exdui主題包, , { }, “微軟雅黑”, 13, , #文本渲染模式_ClearType文本和hinting技術, , , )
MainWindow.掛接窗口 (, Mainhwnd, #主題包_Thunder主題包, , #主程序皮膚, #白色, #標題欄_標題 ＋ #標題欄_關閉按鈕 ＋ #標題欄_最小化按鈕, 255, #底圖方式_九宮排列, , 真, , , )
MainWindow.置客戶區偏移 (10, 10 － 1, -10, -11)
GroupBoxHandle [1] ＝ MSGroupBox [1].創建 (Mainhwnd, 32, 36, 386, 296, “Cookie1”, , , , RGB2ARGB (#白色, 200), , , , , , , )
MSEditBox [1].設置位置 (32, 36)
MSEditBox [1].創建 (GroupBoxHandle [1], 14, 24, 358, 258, , RGB2ARGB (#白色, 200), , , , , 真)
MSPictureFrame [1].創建 (GroupBoxHandle [1], 14, 24, 358, 258, #編輯框1)
MSPictureFrame [1].透明穿透 (真)
GroupBoxHandle [2] ＝ MSGroupBox [2].創建 (Mainhwnd, 532, 36, 386, 296, “Cookie2”, , , , RGB2ARGB (#白色, 200), , , , , , , )
MSPictureFrame [2].創建 (GroupBoxHandle [2], 14, 24, 358, 258, #編輯框1)
MSPictureFrame [2].透明穿透 (真)
MSEditBox [2].設置位置 (532, 36)
MSEditBox [2].創建 (GroupBoxHandle [2], 14, 24, 358, 258, , RGB2ARGB (#白色, 200), , , , , 真)
GroupBoxHandle [3] ＝ MSGroupBox [3].創建 (Mainhwnd, 32, 386, 386, 188, “相同參數”, , , , RGB2ARGB (#白色, 200), , , , , , , )
MSPictureFrame [3].創建 (GroupBoxHandle [3], 14, 24, 358, 160, #編輯框1)
MSPictureFrame [3].透明穿透 (真)
MSEditBox [3].設置位置 (32, 386)
MSEditBox [3].創建 (GroupBoxHandle [3], 14, 24, 358, 160, , RGB2ARGB (#白色, 200), , , , , 真)
GroupBoxHandle [4] ＝ MSGroupBox [4].創建 (Mainhwnd, 532, 386, 386, 188, “不同參數”, , , , RGB2ARGB (#白色, 200), , , , , , , )
MSPictureFrame [4].創建 (GroupBoxHandle [4], 14, 24, 358, 160, #編輯框1)
MSPictureFrame [4].透明穿透 (真)
MSEditBox [4].設置位置 (532, 386)
MSEditBox [4].創建 (GroupBoxHandle [4], 14, 24, 358, 160, , RGB2ARGB (#白色, 200), , , , , 真)
MSGraphicButton.創建 (Mainhwnd, 438, 332, 84, 84)
MSGraphicButton.置狀態圖片 (#按鈕1, #按鈕2, #按鈕3, , )
MSGraphicButton.透明穿透 (真)
MSGraphicButton.事件_被單擊 (&開始對比)
MainWindow.置進入特效 (#特效類型_窗口_漸隱漸顯, , , , #緩動類型_彈性緩動)
MainWindow.置退出特效 (#特效類型_窗口_彈性伸縮, , , , #緩動類型_彈性緩動)
窗口_消息循環 (Mainhwnd)
_FreeLibrary (Ex_hDll)
返回 (0)
.子程序 開始對比
.參數 句柄, 整數型
.參數 X, 整數型
.參數 Y, 整數型
.參數 狀態, 整數型
.局部變量 cookie1數組, 文本型, , "0"
.局部變量 cookie2數組, 文本型, , "0"
.局部變量 i, 整數型
.局部變量 n, 整數型
.局部變量 相同參數, 邏輯型
.局部變量 相同文本, 文本型
.局部變量 不同文本, 文本型
cookie1數組 ＝ 分割文本 (MSEditBox [1].內容 (), “; ”, )
cookie2數組 ＝ 分割文本 (MSEditBox [2].內容 (), “; ”, )
.判斷開始 (取數組成員數 (cookie1數組) ≥ 取數組成員數 (cookie2數組))
  .計次循環首 (取數組成員數 (cookie1數組), i)
    相同參數 ＝ 假
    .計次循環首 (取數組成員數 (cookie2數組), n)
      .如果真 (cookie1數組 [i] ＝ cookie2數組 [n])
        相同參數 ＝ 真
        跳出循環 ()
      .如果真結束
    .計次循環尾 ()
    .如果 (相同參數)
      .如果 (相同文本 ＝ “”)
        相同文本 ＝ cookie1數組 [i]
      .否則
        相同文本 ＝ 相同文本 ＋ #換行符 ＋ cookie1數組 [i]
      .如果結束
    .否則
      .如果 (不同文本 ＝ “”)
        不同文本 ＝ cookie1數組 [i]
      .否則
        不同文本 ＝ 不同文本 ＋ #換行符 ＋ cookie1數組 [i]
      .如果結束
    .如果結束
  .計次循環尾 ()
.判斷 (取數組成員數 (cookie1數組) ≤ 取數組成員數 (cookie2數組))
  .計次循環首 (取數組成員數 (cookie2數組), i)
    相同參數 ＝ 假
    .計次循環首 (取數組成員數 (cookie1數組), n)
      .如果真 (cookie2數組 [i] ＝ cookie1數組 [n])
        相同參數 ＝ 真
        跳出循環 ()
      .如果真結束
    .計次循環尾 ()
    .如果 (相同參數)
      .如果 (相同文本 ＝ “”)
        相同文本 ＝ cookie2數組 [i]
      .否則
        相同文本 ＝ 相同文本 ＋ #換行符 ＋ cookie2數組 [i]
      .如果結束
    .否則
      .如果 (不同文本 ＝ “”)
        不同文本 ＝ cookie2數組 [i]
      .否則
        不同文本 ＝ 不同文本 ＋ #換行符 ＋ cookie2數組 [i]
      .如果結束
    .如果結束
  .計次循環尾 ()
.默認
.判斷結束
MSEditBox [3].內容 (相同文本)
MSEditBox [4].內容 (不同文本)
MSEditBox [3].重畫 ()
MSEditBox [4].重畫 ()