Halcon案例--提取道路

***********************************************Halcon案例***********************************************************

*這個例子演示了如何從空中提取道路。

*對于道路提取，假定道路由具有均勻灰度值和直線的兩個平行邊組成，首先提取空中圖像中的道路中心，然后顯示第一航空影像的放大部分的第二圖像；

*讀取和連續的道路邊緣的輪廓，第二幅圖像中的平行道路邊緣和道路中心確定。最后把這些道路假設結合起來。

read_image (Image, 'mreut4_3')

threshold (Image, Region, 160, 255)

reduce_domain (Image, Region, ImageReduced) 

* 輸入要提取的線寬，直線的對比度，計算參數并提取線

MaxLineWidth := 5

Contrast := 70

calculate_lines_gauss_parameters (MaxLineWidth, Contrast, Sigma, Low, High)

lines_gauss (ImageReduced, RoadCenters, Sigma, Low, High, 'light', 'true', 'bar-shaped', 'true')

* 讀取第二個圖像，顯示第一個圖像的放大圖像部分

read_image (ImagePart, 'mreut_y')

get_image_size (ImagePart, PartWidth, PartHeight)

* 提取、分割輪廓

edges_image (ImagePart, PartAmp, PartDir, 'mderiche2', 0.3, 'nms', 20, 40)

threshold (PartAmp, EdgeRegion, 1, 255)

* 裁剪輪廓區域

clip_region (EdgeRegion, ClippedEdges, 2, 2, PartWidth - 3, PartHeight - 3)

*提取骨架

skeleton (ClippedEdges, EdgeSkeleton)

*轉化為XLD輪廓

gen_contours_skeleton_xld (EdgeSkeleton, EdgeContours, 1, 'filter') 

* 輪廓-多邊形（輪廓-直線段）

gen_polygons_xld (EdgeContours, EdgePolygons, 'ramer', 2)

* 通過提取平行的XLD多邊形來確定道路的邊緣。為了消除錯選，提取的并行多邊形被進一步修改和擴展。

* 提取所有平行XLD多邊形

gen_parallels_xld (EdgePolygons, ParallelEdges, 10, 30, 0.15, 'true')

* 提取平行的XLD多邊形包圍一個均勻區域

mod_parallels_xld (ParallelEdges, ImagePart, ModParallelEdges, ExtParallelEdges, 0.3, 160, 220, 10)

* 通過應用仿射變換從第一張圖像的提取的道路中心提取道路中心

* 生成一個齊次變換矩陣

hom_mat2d_identity (HomMat2DIdentity)

*縮放，x、y方向的縮放因子

hom_mat2d_scale (HomMat2DIdentity, 8, 8, 0, 0, HomMat2DScale)

*平移，x、y方向的平移

hom_mat2d_translate (HomMat2DScale, -250, -600, HomMat2DTranslate)

*將仿射變換應用到道路中心輪廓

affine_trans_contour_xld (RoadCenters, ScaledRoadCenters, HomMat2DTranslate)

* 修剪縮放的道路中心的輪廓然后用多邊形來近似

clip_contours_xld (ScaledRoadCenters, ClippedRoadCenters, 0, 0, 512, 512)

gen_polygons_xld (ClippedRoadCenters, RoadCenterPolygons, 'ramer', 2)

*提取道路邊

combine_roads_xld (EdgePolygons, ModParallelEdges, ExtParallelEdges, RoadCenterPolygons, RoadSides, rad(40), rad(20), 40, 40)