07-存儲管理器實驗

發布時間：2020-08-04 02:26:58 來源：網絡閱讀：1074 作者：少年不在了欄目：系統運維

?S3C2440的存儲控制器提供了訪問外設所需要的信號，它有如下特性：

支持大/小端字節（通過軟件選擇）；
每個BANK的地址空間為128MB，總共1GB(8個BANK)；
可編程控制的總線寬度（8/16／32bit），BANK0只有兩種位寬（16／32bit）；
總共8個BANK：BANK0-BANK5可以支持外接ROM、SRAM等；BANK6-BANK7除了支持ROM、SRAM外，還支持SDRAM等；
BANK0-BANK6七個BANK的起始地址固定；
BANK7的起始地址可編程選擇；
每個BANK的訪問周期均可編程控制；
通過外部的wait信號延長總線的訪問周期；
在外接SDRAM時，支持自刷新和省電模式模式。

?S3C2440對外引出的27根地址線ADDR0-ADDR26的訪問范圍只有128MB，而八個片選信號nGCS0-nGCS7對應于BANK0-BANK7，當訪問BANKx的地址空間時，nGCSx引腳輸出低電平用來選中外接的設備。每個nGCSx對應128MB地址空間，8個nGCSx信號總共對應了1GB。
07-存儲管理器實驗
?在TQ2440開發板中BANK6連接SDRAM，CPU對其提供了一組用于SDRAM的信號：

SDRAM時鐘有效信號LSCKE；
SDRAM時鐘信號LSCLK0/LSCLK1；
數據掩碼信號LnWBE0/LnWBE1/LnWBE2/LnWBE3；
SDRAM行地址選通脈沖信號LnSRAS；
SDRAM列地址選通脈沖信號LnSCAS；
寫允許信號LnWE

07-存儲管理器實驗 ????
1、SDRAM介紹
?SDRAM的內部是一個存儲陣列，如同一個二維表格，將數據填進去。其檢索原理和表格相同，先指定一個行地址，再指定一個列地址就可以準確找到所需要的單元格。這個單元格被稱為存儲單元，而表格則稱為邏輯BANK(L-BANK)，SDRAM一般有4個L-BANK其邏輯圖為上圖所示。
?訪問SDRAM可以分為如下四個步驟：

1、CPU發出的片選信號LnSCS0有效；
2、SDRAM中有4個L-BANK，需要兩根地址線來選中其中一個，從圖中可知使用ADDR24、ADDR25作為L-BANK選擇信號；
3、對選中的芯片進行統一行/列(存儲單元)尋址；
4、找到存儲單元后，被選中的芯片進行同一的數據傳輸。

?在TQ2440開發板中使用了兩片16位的ADRAM芯片并聯組成32位的位寬，與CPU的32根數據線(DATA0-DATA31)相連。BANK6的起始地址為0x30000000，所以SDRAM的訪問地址為0x30000000-ox33ffffff，共64MB。
07-存儲管理器實驗
2、存儲控制器的寄存器使用
?在S3C2440中，存儲控制器一共有13個寄存器，BANK0-BANK5只需要設置BWSCON和BANKCONx(x為0-5)兩個寄存器，BANK6/BANK7外接SDRAM時，除了WSCON和BANKCONx(x為6-7)外，還需要設置REFRESH、BANKSIZE、MRSRB6、MRSRB7等四個寄存器。下面分別說明每個寄存器。
位寬和等待控制寄存器BWSCON

BWSCON	說明
STx	啟動/禁止SDRAM的數據掩碼引腳，對于SDRAM，此位為0；對于SRAM，此位為1
WSx	是否使用存儲器的WAIT信號，通常設為0
DWx	使用兩位來設置相應BANK的位寬，0b00對應8位，0b01對應16位，0b10對應32位，0b11保留

?對于BANK0，它沒有ST0和WS0、DW0([2:1])，bank0只支持兩種位寬16/32。
BANK控制寄存器BANKCONx(x為0-5)，控制BANK0-BANK5外接設備的訪問時序，使用默認的0x0700即可滿足TQ2440開發板。
BANK控制寄存器BANKCONx(x為6-7)，在8個BANK中，只有BANK6和BANK7可以外接SRAM或SDRAM，因此其設置方法有所不同。

BANKCONn	說明
MT [16:15]	用于設置BANK外接的是SRAM或SDRAM，00 = ROM or SRAM，11 = Sync. DRAM
Trcd [3:2]	RAS to CAS delay，推薦設置0b01
SCAN [1:0]	SDRAM的列地址位數，00 = 8-bit 01 = 9-bit 10= 10-bit

刷新控制寄存器REFRESH

REFRESH	說明
REFEN [23]	0，禁止SDRAM的刷新功能，1，開啟SDRAM的刷新功能
TREFMD [22]	SDRAM的刷新模式。0 = CBR/Auto Refresh 1 = Self Refresh(一般系統休眠時使用)
Trp [21:20]	一般設置為0
Tsrc [19:18]	設為默認值11
Refresh Counter [10:0]	SDRAM的刷新值，Refresh period = (211-SDRAM時鐘頻率(MHX)+1)/sdram刷新周期(us)

BANKSIZE寄存器

BANKSIZE	說明
BURST_EN [7]	0，禁止ARM核突發傳輸；1，ARM核支持突發傳輸
SCKE_EN [5]	0，不使用SCKE信號令SDRAM進入省電模式；1，使用SCKE信號令SDRAM進入省電模式
SCLK_EN [4]	0，時刻發出SCLK信號；1，僅在訪問SDRAM期間發出SCLE信號
BK76MAP [2:0]	配置BANK大小

SDRAM模式設置寄存器MRSRBx（6-7）

MRSRBx	說明
CL [6:4]	SDRAM時序的時間參數設置

3、存儲控制器實驗;點亮LED燈
?從NAND Flash啟動CPU時，CPU會通過內部的硬件將NAND Flash開始的4KB數據復制到稱為Steppingstone的4KB的內部RAM中(起始地址為0)，然后跳轉到地址0開始執行。
?本實驗先使用匯編語言設置好存儲控制器，使外接的SDRAM可用，然后把程序本身從Steppingstone復制到SDRAM，最后跳轉到SDRAM中執行。
首先在head.S文件中，完成的工作是設置SDRAM，將程序復制到SDRAM中，然后跳轉到SDRAM繼續執行。

.equ        MEM_CTL_BASE,       0x48000000
.equ        SDRAM_BASE,           0x30000000

.text
.global _start
_start:
    bl  disable_watch_dog               @ 關閉WATCHDOG，否則CPU會不斷重啟
    bl  memsetup                              @ 設置存儲控制器
    bl  copy_steppingstone_to_sdram     @ 復制代碼到SDRAM中
    ldr pc, =on_sdram                             @ 跳到SDRAM中繼續執行
on_sdram:
    ldr sp, =0x34000000                          @ 設置堆棧
    bl  main
halt_loop:
    b   halt_loop

disable_watch_dog:
    @ 往WATCHDOG寄存器寫0即可
    mov r1,     #0x53000000
    mov r2,     #0x0
    str r2,     [r1]
    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:
    @ 將Steppingstone的4K數據全部復制到SDRAM中去
    @ Steppingstone起始地址為0x00000000，SDRAM中起始地址為0x30000000

    mov r1, #0
    ldr r2, =SDRAM_BASE
    mov r3, #4*1024
1:  
    ldr r4, [r1],#4     @ 從Steppingstone讀取4字節的數據，并讓源地址加4
    str r4, [r2],#4     @ 將此4字節的數據復制到SDRAM中，并讓目地地址加4
    cmp r1, r3          @ 判斷是否完成：源地址等于Steppingstone的未地址？
    bne 1b              @ 若沒有復制完，繼續
    mov pc,     lr      @ 返回

memsetup:
    @ 設置存儲控制器以便使用SDRAM等外設

    mov r1,     #MEM_CTL_BASE       @ 存儲控制器的13個寄存器的開始地址
    adrl    r2, mem_cfg_val                 @ 這13個值的起始存儲地址
    add r3,     r1, #52                          @ 13*4 = 54
1:  
    ldr r4,     [r2], #4            @ 讀取設置值，并讓r2加4
    str r4,     [r1], #4            @ 將此值寫入寄存器，并讓r1加4
    cmp r1,     r3                  @ 判斷是否設置完所有13個寄存器
    bne 1b                          @ 若沒有寫成，繼續
    mov pc,     lr                  @ 返回

.align 4
mem_cfg_val:
    @ 存儲控制器13個寄存器的設置值
    .long   0x22011110      @ BWSCON
    .long   0x00000700      @ BANKCON0
    .long   0x00000700      @ BANKCON1
    .long   0x00000700      @ BANKCON2
    .long   0x00000700      @ BANKCON3  
    .long   0x00000700      @ BANKCON4
    .long   0x00000700      @ BANKCON5
    .long   0x00018005      @ BANKCON6
    .long   0x00018005      @ BANKCON7
    .long   0x008C07A3      @ REFRESH
    .long   0x000000B1      @ BANKSIZE
    .long   0x00000030      @ MRSRB6
    .long   0x00000030      @ MRSRB7

在leds.c文件中，完成led循環閃爍的實驗：


#define GPBCON      (*(volatile unsigned long *)0x56000010)
#define GPBDAT      (*(volatile unsigned long *)0x56000014)

/*
 * LED1,LED2,LED4對應GPB5、GPB6、GPB7、GPB8
 */
#define GPB5_out    (1<<(5*2))
#define GPB6_out    (1<<(6*2))
#define GPB7_out    (1<<(7*2))
#define GPB8_out    (1<<(8*2))

void  wait(volatile unsigned long dly)
{
    for(; dly > 0; dly--);
}

int main(void)
{
    unsigned long i = 0;

    // LED1,LED2,LED3,LED4對應的4根引腳設為輸出
    GPBCON = GPB5_out | GPB6_out | GPB7_out | GPB8_out;

    while(1){
        wait(30000);
        GPBDAT = (~(i<<5));     // 根據i的值，點亮LED1,2,3,4
        if(++i == 16)
            i = 0;
    }

    return 0;
}

Makefile的編寫為：

sdram.bin : head.S  leds.c
    arm-linux-gcc  -c -o head.o head.S
    arm-linux-gcc -c -o leds.o leds.c
    arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf     #鏈接代碼段的起始地址為0x30000000
    arm-linux-objcopy -O binary -S sdram_elf sdram.bin
    arm-linux-objdump -D -m arm  sdram_elf > sdram.dis
clean:
    rm -f   sdram.dis sdram.bin sdram_elf *.o

代碼的具體流程圖為：
???? 07-存儲管理器實驗
???

實驗結果：

?相比于直接在內部SRAM運行結果，可以發現在外部SDRAM運行的LED點燈程序，LED閃爍變慢。本程序只能將內部SRAM的4KB程序復制到外部SDRAM，當程序大于4KB時，要復制4KB后的代碼，就需要使用NAND Flash控制器。
實驗代碼