STC15單片機驅動WS2812B七彩LED（匯編混合編程）

WS2812B七彩LED具有集成度高、使用方便等特點，但是800K的數據速率（IO變化速率高達2.4M），對單片機提出了較高的要求，通常是采用SPI+DMA方式驅動，

也有人采用匯編實現，但是要預先把數據轉換為按bit存放，在LED級連數量較多的情況下，需要占用極多的存儲空間。

在驅動WS2812B上花費了太多的時間，走了不少彎路，記錄下來：

• 簡易數字分析儀采樣頻率最高只有4M，即測量精度為250ns，而信號寬度要求為400ns和850ns，這樣測量的結果存在較大的誤差，讓人誤以為信號跳變無規律，
  迷失了方向；解決的辦法就是利用STC單片機主時鐘的內分頻功能，語句：CLK_DIV |= 0x07; 將主頻降低128倍，這樣測量的波形就足夠準確了。
• STC15系列可以使用內置振蕩電路，主頻高達27M，高速才有足夠的時間進行數據處理，最終選擇的是24M的主頻。
• 匯編與C混合編程，開始以為很復雜，做了發現不是很困難，主要還是對匯編本身的理解。
  1、形式上，在C語言中通過#pragma ASM和#pragma ENDASM內嵌匯編語句；
  2、編譯器在使用內嵌語句的文件右鍵菜單選擇Option，選中Generate assembler SRC file 和 assemble SRC file；
  3、子程序調用時的參數傳遞上，一般是用R7，R5，R3，具體可以看編譯生成的SRC文件；
• 最初采用高級語言的兩層循環嵌套，內層通過移位實現8個比特輸出，外層依次處理每個比特，但是兩層循環之間的時延較長，導致輸出的波形不規則；
  最終打破結構化編程的框架，利用每個比特中850ns輸出的長信號進行數據處理，實現了完美波形輸出；
• 在LED數量較多的情況下，發現會有閃爍，經常時間的查找，最后判斷是信號輸出期間產生硬件中斷，導致輸出的波形有跳變，導致不特定位置的LED出現閃爍；

128分頻下的輸出波形

源代碼：

void WS2812_SendArray(uchar xdata *pSource, uchar length) {
    EA    =    0;
#pragma ASM
    CLR      WS5050_DI
    MOV R1,#160
SA_DELAY25:
    DJNZ    R1, SA_DELAY25
    MOV R1,#160
SA_DELAY25_2:
    DJNZ    R1, SA_DELAY25_2

;    R5:length, R1:8bit, R4:臨時存儲A
    MOV        DPH, R6
    MOV        DPL, R7
    MOVX    A, @DPTR
    MOV      R1,#8        ;2
SA_BIT_PHASE0:
    SETB    WS5050_DI    ;4
    NOP                    ;1
    RLC      A            ;1
    JC        SA_BIT_1    ;3
    NOP                    ;1
    CLR        WS5050_DI    ;4
    CJNE    R1, #1, SA_BIT0_NOT8    ;4
;    當寄存器R1=1，說明是最后一位，則準備下一字節
    INC        DPTR        ;1
    MOVX    A, @DPTR    ;2
    MOV      R1,#9        ;2
    DJNZ    R5, SA_PHASE3    ;4
;    R5=0,結束
    SJMP    SA_END    ;3
SA_BIT0_NOT8:
;    R1>1,前七位
    XCH        A, R4        ;2
    MOVX    A, @DPTR    ;2
    XCH        A, R4        ;2
    NOP
    SJMP    SA_PHASE3    ;3
SA_BIT_1:
    CJNE    R1, #1, SA_BIT1_NOT8    ;4
;    當寄存器R1=1，說明是最后一位，則準備下一字節
    INC        DPTR        ;1
    MOVX    A, @DPTR    ;2
    MOV      R1,#9        ;2
    NOP
    DJNZ    R5, SA_BIT1_9TH    ;4
;    R5=0,結束
    SJMP    SA_END    ;3
SA_BIT1_NOT8:
    XCH        A, R4        ;2
    MOVX    A, @DPTR    ;2
    XCH        A, R4        ;2
    NOP
    NOP
    NOP
SA_BIT1_9TH:
    CLR        WS5050_DI
    NOP                    ;1
    NOP                    ;1
SA_PHASE3:
    DJNZ    R1, SA_BIT_PHASE0    ;4

SA_END:
    SETB    WS5050_DI
#pragma ENDASM
    EA    =    1;
    pSource = 0;
    length = 0;
}