如何實現關閉IDE通道檢測的批處理

這篇文章主要為大家展示了“如何實現關閉IDE通道檢測的批處理”，內容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領大家一起研究并學習一下“如何實現關閉IDE通道檢測的批處理”這篇文章吧。

示例

:: 修改IDE通道檢測設備模式，不接設備的設置為無，提高XP啟動速度 
:: 建議在系統第二次重新啟動檢測到所有已經安裝的IDE設備后運行 
@set _debug= 
@echo %_debug% off & setlocal ENABLEDELAYEDEXPANSION 
set hkey1=HKLM\SYSTEM\CurrentControlSet\Enum\PCIIDE\IDEChannel 
set hkey2=HKLM\SYSTEM\CurrentControlSet\Control\Class 
for /f "usebackq tokens=*" %%I in (`reg query %hkey1% ^| find /i "IDEChannel\"`) do call :_check "%%I" 
goto :eof 
:_check 
::echo %1 
set subkey= 
for /f "usebackq tokens=3*" %%J in (`reg query %1 ^| find /i "driver"`) do set subkey=%%J 
set DriverDesc= 
for /f "usebackq tokens=3,4*" %%K in (`reg query "%hkey2%\%subkey%" /v DriverDesc ^| find /i "driverdesc"`) do set DriverDesc=%%K %%L 通道 
reg query "%hkey2%\%subkey%" /v MasterDeviceType | find /i "0x1" > nul 
if %errorlevel%==1 goto _ChgMaster 
goto _CheckSlave 
:_ChgMaster 
reg add "%hkey2%\%subkey%" /v UserMasterDeviceType /t REG_DWORD /d 3 /f 
echo “%DriverDesc%”的設備0檢測方式設置為無。 
:_CheckSlave 
reg query "%hkey2%\%subkey%" /v SlaveDeviceType | find /i "0x1" > nul 
if %errorlevel%==1 goto _ChgSlave 
goto :eof 
:_ChgSlave 
reg add "%hkey2%\%subkey%" /v UserSlaveDeviceType /t REG_DWORD /d 3 /f 
echo “%DriverDesc%”的設備1檢測方式設置為無。 
goto :eof

以上是“如何實現關閉IDE通道檢測的批處理”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！