批處理如何實現網站屏蔽與解除屏蔽

這篇文章主要為大家展示了“批處理如何實現網站屏蔽與解除屏蔽”，內容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領大家一起研究并學習一下“批處理如何實現網站屏蔽與解除屏蔽”這篇文章吧。

@echo off&color 0f&title 網址 屏蔽/解除屏蔽
:loop
setlocal EnableDelayedExpansion
set wjm=C:\WINDOWS\system32\drivers\etc
set "str=127.0.0.1     "
set "xsxx=echo\&echo               注： 此操作需要經過殺毒軟件的同意。"
set "xsxx=%xsxx%&echo               ==================================&echo\"
cls&%xsxx%
echo\&echo 以下是已經被屏蔽的網址&echo ======================&echo\
for /f "tokens=1* delims= " %%a in (%wjm%\hosts) do (
  if "%%a"=="127.0.0.1" set /a xs+=1
  if !xs! geq 2 (
  set /a num+=1
  set !num!=%%b&echo ^(!num!^) %%b
  )
  set no=%%a %%b
)
echo\
if "%no%"=="127.0.0.1 localhost" (cls&%xsxx%&echo\&echo 目前沒有被屏蔽的網址。
echo =====================&echo\&echo\&echo\&echo\)
if defined pinbi goto jiec
if defined pinbi3 goto quan
echo\&echo 請選擇 1 屏蔽網址，2 解除屏蔽。3 全部解除屏蔽。&echo\
set /p xuan=請選擇 [ 1,2,3 ] ? 
if "%xuan%"=="2" (endlocal&set pinbi=a&goto loop)
if "%xuan%"=="3" (endlocal&set pinbi3=%num%&goto loop)
cls&%xsxx%
echo\&echo 請輸入需要“屏蔽”的“單個”網址。
echo\&echo 或 先在“某文檔”里輸入所有要屏蔽的網址，一行一個。
echo\&echo 再在這里輸入 “文檔名” （含全路徑和后綴名），可批量添加。
echo\&echo 按“回車鍵”或“點關閉按鈕”退出。。。&echo\
set /p wdm=請輸入文檔名或網址：
if "%wdm%"=="" exit
if not exist %wdm% set wdm="%wdm%"
for /f "delims=" %%a in (%wdm%) do (
  color cf&echo !str!%%a>>%wjm%\hosts
)
cls&echo\&echo 屏蔽成功。。。
endlocal&set pinbi=
goto loop
:jiec
echo\&echo 輸入已經屏蔽的網址前面的序號，解除屏蔽相應的網址。
echo\&echo 解除屏蔽,可一次輸入多個序號，用空格分開。如：1 2 5 10 （即：解除1、2、5、10）
echo\&echo 按“回車鍵”或“點關閉按鈕”退出。。。&echo\
set /p wz=請輸入序號：
if not defined wz exit
:quan
cd.>%wjm%\hosts1
color 1f
if defined pinbi3 for /l %%i in (1 1 %pinbi3%) do set wz=!wz! %%i
for /f "delims=" %%a in (%wjm%\hosts) do (
  set pin=
  for %%i in (%wz%) do if "%%a"=="!str!!%%i!" set pin=a
  if not defined pin echo %%a>>%wjm%\hosts1
)
del/q %wjm%\hosts
ren %wjm%\hosts1 hosts
del/q %wjm%\hosts1
cls&echo\&echo 解除屏蔽成功。。。
endlocal&set pinbi=&set pinbi3=
goto loop

以上是“批處理如何實現網站屏蔽與解除屏蔽”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注億速云行業資訊頻道！