VBS怎么實現將當前時間轉換成UTC時間

本篇內容介紹了“VBS怎么實現將當前時間轉換成UTC時間”的有關知識，在實際案例的操作過程中，不少人都會遇到這樣的困境，接下來就讓小編帶領大家學習一下如何處理這些情況吧！希望大家仔細閱讀，能夠學有所成！

例如下面的代碼在當前時間返回：1368299689

Option Explicit
 
Dim dtmDate
 
If WScript.Arguments.Named.Count > 0 Then Syntax
 
With WScript.Arguments.Unnamed
  ' Check command line arguments
  If .Count = 0 Then dtmDate = Now
  If .Count > 0 Then dtmDate = .Item(0)
  If .Count > 1 Then dtmDate = dtmDate & " " & .Item(1)
  If .Count > 2 Then dtmDate = dtmDate & " " & .Item(2)
  If .Count > 3 Then Syntax
  On Error Resume Next
  dtmDate = CDate( dtmDate )
  If Err Then
    On Error Goto 0
    Syntax
  End If
  On Error Goto 0
  If Not IsDate( dtmDate ) Then Syntax
End With
 
' Calculate and display the result
WScript.Echo DateDiff( "s", "1970-01-01 00:00:00", dtmDate )
 
 
Sub Syntax
  WScript.Echo vbcrlf _
        & "Date2UTC.vbs, Version 1.00" _
        & vbCrLf _
        & "Convert any date/time to Unix time (UTC)" _
        & vbCrLf & vbCrLf _
        & "Usage: CSCRIPT.EXE //NoLogo Date2UTC.vbs date [ time ]" _
        & vbCrLf & vbCrLf _
        & "Where: ""date""  is the date to convert (default: current date/time)" _
        & vbCrLf _
        & "    ""time""  is the optional time to convert" _
        & vbCrLf & vbCrLf _
        & "Notes: Though often called UTC, Unix time does not take into account leap" _
        & vbCrLf _
        & "    seconds, while ""official"" UTC does." _
        & vbCrLf _
        & "    If the specified date is ambiguous, the current user's date" _
        & vbCrLf _
        & "    and time format is assumed." _
        & vbCrLf & vbCrLf _
        & "Written by Rob van der Woude" _
        & vbCrLf _
        & "http://www.robvanderwoude.com"
  WScript.Quit 1
End Sub

“VBS怎么實現將當前時間轉換成UTC時間”的內容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業相關的知識可以關注億速云網站，小編將為大家輸出更多高質量的實用文章！