怎么在VBS中讀取配置文件的配置項

怎么在VBS中讀取配置文件的配置項？針對這個問題，這篇文章詳細介紹了相對應的分析和解答，希望可以幫助更多想解決這個問題的小伙伴找到更簡單易行的方法。

以下是一個讀取配置文件的函數:
本函數僅適用于以下格式的配置文件(.ini,.txt,.inf):

[Mark1]
key1=key1value
key2=key2value
........
[Mark2]
key1=key1value
key2=key2value

核心代碼

Function GetConfig(FilePath,Mark,Key)
 Dim fso, Str_ReadLine
 Set fso = CreateObject("Scripting.FileSystemObject")
 '判斷配置文件是否存在
 If fso.FileExists(FilePath) Then
 '初始化配置標記,默認為未找到
 Flag = 0
 '打開配置文件
 Set ConfigFile = fso.opentextfile(FilePath, 1)
 '循環讀取文件數據行
 Do
  Str_ReadLine = ConfigFile.ReadLine
  WScript.Echo Str_ReadLine
  '判斷讀取的數據行是否為空
  If Str_ReadLine <> "" Then
  '判斷讀取數據行是否為需要查找的配置開始標記
  If LCase(Trim(Str_ReadLine))="[" & Lcase(Mark) & "]" Then
   '找到配置開始標記
   Flag = 1  
   '循環讀取當前配置開始標記下的配置項,直到在當前配置標記下找到所需配置項
   '或下一個配置項開始標記出現時退出
   Do
   Str_ReadLine = ConfigFile.ReadLine
   retNum = InStr(Str_ReadLine,"=")
   '檢查讀取的配置項是否有等號
   If retNum > 0 Then
    '判斷獲取配置項名稱是否為所需的配置項
    If Trim(LCase(Left(Str_ReadLine,retNum-1)))= Trim(LCase(Key)) Then
    '獲取配置項等號后的數據
    GetConfig = Trim(Right(Str_ReadLine,Len(Str_ReadLine)-retNum))
    '找到后,退出函數
    Exit Function 
    End If
   End If
   '判斷當前是否為下一個配置項開始標記
   If (InStr(Str_ReadLine,"[")>0 And InStr(Str_ReadLine,"]")>0) Then
    '標記當前配置項開始標記為下一個配置
    Flag = 0
    '退出函數
    Exit Function
   End If
   Loop Until (Flag = 0 Or ConfigFile.AtEndOfStream)
  End If
  End If 
 Loop Until ConfigFile.AtEndOfStream
 '關閉文件
 ConfigFile.Close
 Set fso = Nothing
 Else
 '文件未找到,給出提示信息
 MsgBox "配置文件"&"[" & FilePath &"]不存在,請檢查路徑是否正確."
 End If
End Function

實例:

我們需要讀取d:\config\environment.ini文件的[Computer2]下的IP項的值,文件內容如下:

[Computer1]
ComputerName=Computer1
IP=192.168.1.1
[Computer2]
ComputerName=Computer2
IP=192.168.1.2

使用以上函數即可獲取

IP = GetConfig("d:\config\environment.ini","Computer2","IP")
Msgbox IP

關于怎么在VBS中讀取配置文件的配置項問題的解答就分享到這里了，希望以上內容可以對大家有一定的幫助，如果你還有很多疑惑沒有解開，可以關注億速云行業資訊頻道了解更多相關知識。