易語言純IP數據庫查詢的示例分析

這篇文章主要介紹易語言純IP數據庫查詢的示例分析，文中介紹的非常詳細，具有一定的參考價值，感興趣的小伙伴們一定要看完！

以下是我們給大家分享了易語言IP數據庫查詢相關的內容代碼，大家可以測試下

.版本 2
.支持庫 spec

.程序集 程序集1

.子程序 _啟動子程序, 整數型, , 請在本子程序中放置易模塊初始化代碼


_臨時子程序 () ' 在初始化代碼執行完畢后調用測試代碼
返回 (0) ' 可以根據您的需要返回任意數值

.子程序 _臨時子程序

' 本名稱子程序用作測試程序用，僅在開發及調試環境中有效，編譯發布程序前將被系統自動清空，請將所有用作測試的臨時代碼放在本子程序中。 ***注意不要修改本子程序的名稱、參數及返回值類型。
調試輸出 (查詢IP歸屬地 (“192.168.0.0”))


.子程序 查詢IP歸屬地, 文本型, 公開, 查詢IP地址的地理位置
.參數 IP地址, 文本型, , 可以是域名
.參數 數據庫文件名, 文本型, 可空
.局部變量 文件號, 整數型
.局部變量 文件頭字節集, 字節集
.局部變量 IP數量, 長整數型
.局部變量 計次變量, 整數型
.局部變量 開始IP字節集, 字節集
.局部變量 結束IP偏移, 長整數型
.局部變量 結束IP字節集, 字節集
.局部變量 地區偏移, 長整數型
.局部變量 查詢IP數值, 長整數型
.局部變量 地區文本, 文本型
.局部變量 IP段信息, 文本型
.局部變量 開始IP讀取位置, 長整數型
.局部變量 開始ip, 文本型
.局部變量 結束IP, 文本型
.局部變量 first_start_ip_offset, 長整數型
.局部變量 last_start_ip_offset, 長整數型
.局部變量 開始IP數值, 長整數型
.局部變量 結束IP數值, 長整數型

.如果真 (IP地址 ＝ “”)
  返回 (“”)
.如果真結束
.如果真 (是否為空 (數據庫文件名))
  數據庫文件名 ＝ “.\QQWry.dat”
.如果真結束
文件號 ＝ 打開文件 (數據庫文件名, #讀入, #無限制)
.如果真 (文件號 ＝ 0)
  信息框 (“沒找到數據庫”, 0, , )
  返回 (“”)
.如果真結束
文件頭字節集 ＝ 讀入字節集 (文件號, 8)
first_start_ip_offset ＝ 取字節集數據 (取字節集左邊 (文件頭字節集, 4), #整數型, )
last_start_ip_offset ＝ 取字節集數據 (取字節集右邊 (文件頭字節集, 4), #整數型, )
IP數量 ＝ (last_start_ip_offset － first_start_ip_offset) ＼ 7 ＋ 1
查詢IP數值 ＝ IP文本轉整數值 (IP地址)
開始IP讀取位置 ＝ 二分法確定位置 (文件號, first_start_ip_offset, 1, IP數量, 查詢IP數值)
移動讀寫位置 (文件號, , first_start_ip_offset ＋ (開始IP讀取位置 － 1) × 7)
開始IP字節集 ＝ 讀入字節集 (文件號, 7)
開始ip ＝ IP文本補位 (取十六進制文本 (取字節集數據 (取字節集左邊 (開始IP字節集, 4), #整數型, )))
結束IP偏移 ＝ 取字節集數據 (取字節集右邊 (開始IP字節集, 3), #整數型, )
移動讀寫位置 (文件號, , 結束IP偏移)
結束IP字節集 ＝ 讀入字節集 (文件號, 4)
結束IP ＝ IP文本補位 (取十六進制文本 (取字節集數據 (結束IP字節集, #整數型, )))
地區偏移 ＝ 結束IP偏移 ＋ 4
開始IP數值 ＝ 十六進制到十進制 (開始ip)
結束IP數值 ＝ 十六進制到十進制 (結束IP)
.如果真 (查詢IP數值 ≥ 開始IP數值 且 查詢IP數值 ≤ 結束IP數值)
  地區文本 ＝ 取地區文本 (文件號, 地區偏移)
.如果真結束
關閉文件 (文件號)
返回 (地區文本)


.子程序 二分法確定位置, 整數型
.參數 文件號, 整數型
.參數 基址, 長整數型
.參數 初始位置, 長整數型
.參數 結束位置, 長整數型
.參數 查詢值, 長整數型
.局部變量 中間讀寫位置, 長整數型
.局部變量 中間位置, 長整數型
.局部變量 中間IP文本, 文本型
.局部變量 中間IP數值, 長整數型
.局部變量 結束讀寫位置, 長整數型
.局部變量 結束IP文本, 文本型
.局部變量 結束IP數值, 長整數型

中間位置 ＝ (初始位置 ＋ 結束位置) ＼ 2
.如果真 (初始位置 ＝ 中間位置)
  返回 (初始位置)
.如果真結束
結束讀寫位置 ＝ 基址 ＋ (結束位置 － 1) × 7
移動讀寫位置 (文件號, , 結束讀寫位置)
結束IP文本 ＝ IP文本補位 (取十六進制文本 (取字節集數據 (取字節集左邊 (讀入字節集 (文件號, 7), 4), #整數型, )))
結束IP數值 ＝ 十六進制到十進制 (結束IP文本)
.如果真 (查詢值 ≥ 結束IP數值)
  返回 (結束位置)
.如果真結束
中間讀寫位置 ＝ 基址 ＋ (中間位置 － 1) × 7
移動讀寫位置 (文件號, , 中間讀寫位置)
中間IP文本 ＝ IP文本補位 (取十六進制文本 (取字節集數據 (取字節集左邊 (讀入字節集 (文件號, 7), 4), #整數型, )))
中間IP數值 ＝ 十六進制到十進制 (中間IP文本)
.如果真 (查詢值 ＜ 中間IP數值)
  .如果真 (結束位置 － 初始位置 ＝ 1)
    返回 (初始位置)
  .如果真結束
  返回 (二分法確定位置 (文件號, 基址, 初始位置, 中間位置, 查詢值))
.如果真結束
.如果真 (查詢值 ＞ 中間IP數值)
  返回 (二分法確定位置 (文件號, 基址, 中間位置, 結束位置, 查詢值))
.如果真結束
.如果真 (查詢值 ＝ 中間IP數值)
  返回 (中間位置)
.如果真結束
返回 (0)

.子程序 取地區文本, 文本型
.參數 文件號, 整數型
.參數 地區偏移, 整數型
.局部變量 首字節集, 字節集
.局部變量 偏移, 整數型
.局部變量 國家記錄, 文本型
.局部變量 地區記錄, 文本型
.局部變量 長度, 整數型

移動讀寫位置 (文件號, , 地區偏移)
首字節集 ＝ 讀入字節集 (文件號, 1)
.判斷開始 (首字節集 ＝ { 1 }) ' 模式1的國家記錄后面不會再有地區記錄
  偏移 ＝ 取字節集數據 (讀入字節集 (文件號, 3), #整數型, )
  國家記錄 ＝ 讀國家記錄 (文件號, 偏移, 長度)
  偏移 ＝ 偏移 ＋ 長度

  地區記錄 ＝ 讀地區記錄 (文件號, 偏移)

.判斷 (首字節集 ＝ { 2 }) ' 模式2的國家記錄后會有地區記錄
  偏移 ＝ 取字節集數據 (讀入字節集 (文件號, 3), #整數型, )
  國家記錄 ＝ 讀國家記錄 (文件號, 偏移, 長度)
  偏移 ＝ 地區偏移 ＋ 4
  地區記錄 ＝ 讀地區記錄 (文件號, 偏移)

.默認
  偏移 ＝ 地區偏移
  國家記錄 ＝ 讀國家記錄 (文件號, 偏移, 長度)

  偏移 ＝ 偏移 ＋ 長度
  地區記錄 ＝ 讀地區記錄 (文件號, 偏移)
.判斷結束

.如果真 (到大寫 (刪首尾空 (地區記錄)) ＝ “CZ88.NET”)
  地區記錄 ＝ “”
.如果真結束
.如果真 (地區記錄 ＝ “” 且 國家記錄 ≠ “”)
  返回 (國家記錄)
.如果真結束
.如果真 (地區記錄 ≠ “” 且 國家記錄 ＝ “”)
  返回 (地區記錄)
.如果真結束
.如果真 (國家記錄 ＝ 地區記錄)
  返回 (國家記錄)
.如果真結束
返回 (國家記錄 ＋ “ ” ＋ 地區記錄)

.子程序 讀國家記錄, 文本型
.參數 文件號, 整數型
.參數 地區偏移, 整數型
.參數 長度, 整數型, 參考, 記錄所占的長度
.局部變量 首字節集, 字節集
.局部變量 偏移, 整數型
.局部變量 國家記錄, 文本型
.局部變量 記錄長度, 整數型

移動讀寫位置 (文件號, #文件首, 地區偏移)
首字節集 ＝ 讀入字節集 (文件號, 1)
.如果 (首字節集 ＝ { 2 }) ' 第2次重定向一定是模式2
  偏移 ＝ 取字節集數據 (讀入字節集 (文件號, 3), #整數型, )
  移動讀寫位置 (文件號, #文件首, 偏移)
  首字節集 ＝ 讀入字節集 (文件號, 1)
  .如果 (首字節集 ＝ { 2 } 或 首字節集 ＝ { 1 }) ' 可能有錯誤,不管了
    偏移 ＝ 取字節集數據 (讀入字節集 (文件號, 3), #整數型, )
    移動讀寫位置 (文件號, #文件首, 偏移)

  .否則
    ' 不是重定向
    移動讀寫位置 (文件號, #現行位置, -1) ' 移動回去 上面讀過一字節數據了

  .如果結束
  國家記錄 ＝ 讀入文本 (文件號, )
  長度 ＝ 4
.否則
  ' 不是重定向
  移動讀寫位置 (文件號, #現行位置, -1) ' 移動回去 上面讀過一字節數據了
  國家記錄 ＝ 讀入文本 (文件號, )
  記錄長度 ＝ 取文本長度 (國家記錄)
  長度 ＝ 記錄長度 ＋ 1
.如果結束

返回 (國家記錄)

.子程序 讀地區記錄, 文本型
.參數 文件號, 整數型
.參數 地區偏移
.局部變量 首字節集, 字節集
.局部變量 偏移, 整數型
.局部變量 地區記錄, 文本型

移動讀寫位置 (文件號, #文件首, 地區偏移)
首字節集 ＝ 讀入字節集 (文件號, 1)
.如果 (首字節集 ＝ { 1 } 或 首字節集 ＝ { 2 }) ' 對于地區記錄，模式1和模式2是一樣的
  偏移 ＝ 取字節集數據 (讀入字節集 (文件號, 3), #整數型, )
  移動讀寫位置 (文件號, #文件首, 偏移)
  首字節集 ＝ 讀入字節集 (文件號, 1)
  .如果 (首字節集 ＝ { 1 } 或 首字節集 ＝ { 2 }) ' 再來判斷下是否是重定向,安全第一
    偏移 ＝ 取字節集數據 (讀入字節集 (文件號, 3), #整數型, )
    移動讀寫位置 (文件號, #文件首, 偏移)
  .否則
    ' 不是重定向
    移動讀寫位置 (文件號, #現行位置, -1) ' 移動回去 上面讀過一字節數據了
  .如果結束

.否則
  ' 不是重定向
  移動讀寫位置 (文件號, #現行位置, -1) ' 移動回去 上面讀過一字節數據了
.如果結束

地區記錄 ＝ 讀入文本 (文件號, )
返回 (地區記錄)

.子程序 IP文本轉整數值, 長整數型
.參數 IP文本, 文本型
.局部變量 IP變量數組, 文本型, , "0"
.局部變量 十六進制IP文本, 文本型
.局部變量 十進制值, 長整數型
.局部變量 新ip, 文本型
.局部變量 i, 整數型
.局部變量 IP段, 文本型

IP變量數組 ＝ 分割文本 (IP文本, “.”, )
.如果真 (取數組成員數 (IP變量數組) ≠ 4)
  新ip ＝ 轉換為IP地址 (IP文本)
  IP變量數組 ＝ 分割文本 (新ip, “.”, )
  .如果真 (取數組成員數 (IP變量數組) ≠ 4)
    返回 (0)
  .如果真結束

.如果真結束
十六進制IP文本 ＝ “”
.計次循環首 (4, i)
  IP段 ＝ 取文本右邊 (“00” ＋ 取十六進制文本 (到整數 (IP變量數組 [5 － i])), 2)
  十六進制IP文本 ＝ 十六進制IP文本 ＋ IP段
.計次循環尾 ()
十進制值 ＝ 十六進制到十進制 (倒轉十六進制文本 (十六進制IP文本))
返回 (十進制值)

.子程序 十六進制到十進制, 長整數型
.參數 十六進制文本, 文本型
.局部變量 字節集, 字節集
.局部變量 字節集長度, 整數型
.局部變量 最終值, 長整數型
.局部變量 i, 整數型, , , 中間循環變量
.局部變量 臨時數值, 整數型, , , 每一位上的值

字節集 ＝ 到字節集 (到大寫 (十六進制文本))
字節集長度 ＝ 取字節集長度 (字節集)
.計次循環首 (字節集長度, i)
  臨時數值 ＝ 字節集 [字節集長度 － i ＋ 1]
  .如果真 (臨時數值 ＞ 64 且 臨時數值 ＜ 71) ' A=65 F=70
    最終值 ＝ 最終值 ＋ (臨時數值 － 65 ＋ 10) × 求次方 (16, i － 1)
    到循環尾 ()
  .如果真結束
  最終值 ＝ 最終值 ＋ 到整數 (字符 (臨時數值)) × 求次方 (16, i － 1)
.計次循環尾 ()
返回 (最終值)

.子程序 倒轉十六進制文本, 文本型
.參數 IP地址文本, 文本型
.局部變量 計次變量, 整數型
.局部變量 臨時文本, 文本型
.局部變量 結果文本, 文本型

臨時文本 ＝ IP文本補位 (IP地址文本)
.計次循環首 (4, 計次變量)
  結果文本 ＝ 結果文本 ＋ 取文本中間 (臨時文本, 8 － 計次變量 × 2 ＋ 1, 2)
.計次循環尾 ()
返回 (結果文本)


.子程序 IP文本補位, 文本型
.參數 IP地址文本, 文本型
.局部變量 文本長度, 整數型
.局部變量 臨時文本, 文本型
.局部變量 計次變量, 整數型

臨時文本 ＝ IP地址文本
文本長度 ＝ 取文本長度 (IP地址文本)
.如果真 (文本長度 ＜ 8)
  臨時文本 ＝ 取重復文本 (8 － 文本長度, “0”) ＋ 臨時文本
.如果真結束
返回 (臨時文本)

.子程序 十六進制文本到IP地址, 文本型
.參數 IP文本, 文本型
.局部變量 臨時文本, 文本型
.局部變量 結果文本, 文本型
.局部變量 計次變量, 整數型
.局部變量 結果ip, 文本型, , "4"
.局部變量 IP地址, 文本型

臨時文本 ＝ IP文本補位 (IP文本)
.計次循環首 (4, 計次變量)
  結果文本 ＝ 取文本中間 (臨時文本, 1 ＋ (計次變量 － 1) × 2, 2)
  IP地址 ＝ IP地址 ＋ 到文本 (十六進制到十進制 (結果文本)) ＋ “.”
.計次循環尾 ()
返回 (取文本左邊 (IP地址, 取文本長度 (IP地址) － 1))

以上是“易語言純IP數據庫查詢的示例分析”這篇文章的所有內容，感謝各位的閱讀！希望分享的內容對大家有幫助，更多相關知識，歡迎關注億速云行業資訊頻道！