易語言如何獲取網頁端的好友管理頁面信息導出QQ好友

這篇文章給大家分享的是有關易語言如何獲取網頁端的好友管理頁面信息導出QQ好友的內容。小編覺得挺實用的，因此分享給大家做個參考，一起跟隨小編過來看看吧。

全局變量表

.版本 2
.全局變量 Cookie_Overall, 文本型
.全局變量 BKN_Overall, 文本型

QQ快捷啟動的代碼

.版本 2
.程序集 窗口程序集_窗口1
.子程序 _超文本瀏覽框1_跳轉完畢
.局部變量 Cookie, 文本型
.局部變量 Uin, 文本型
.局部變量 Skey, 文本型
Cookie ＝ 網頁_取Cookie (“qun.qq.com”)
.如果真 (尋找文本 (Cookie, “p_skey”, , 假) ≠ -1)
  Uin ＝ 文本_取出中間文本 (Cookie, “p_uin=o”, “;”)
  Skey ＝ 文本_取出中間文本 (Cookie, “skey=”, “;”)
  BKN_Overall ＝ Get_BKN (Skey)
  Cookie_Overall ＝ Cookie
  _啟動窗口.按鈕_快速登錄.標題 ＝ “已登錄”
  _啟動窗口.標簽_QQ號碼.標題 ＝ “QQ號碼：” ＋ 到文本 (到整數 (Uin))
  _啟動窗口.圖片框1.圖片 ＝ Get_QQHEAD (Uin)
  初始化 ()
  銷毀 ()
.如果真結束

獲取代碼

.版本 2
.程序集 程序集1
.子程序 Get_BKN, 文本型
.參數 Skey, 文本型
.局部變量 基值, 整數型
.局部變量 計數, 整數型
.局部變量 長度, 整數型
.局部變量 結果, 整數型
基值 ＝ 5381
計數 ＝ 0
長度 ＝ 取文本長度 (Skey)
.判斷循環首 (計數 ＜ 長度)
  基值 ＝ 基值 ＋ 左移 (基值, 5) ＋ 取代碼 (Skey, 計數 ＋ 1)
  計數 ＝ 計數 ＋ 1
.判斷循環尾 ()
結果 ＝ 位與 (基值, 2147483647)
返回 (到文本 (結果))
.子程序 Get_QQHEAD, 字節集
.參數 Uin, 文本型
.局部變量 Url, 文本型
Url ＝ “http://q4.qlogo.cn/g?b=qq&nk=” ＋ Uin ＋ “&s=140”
返回 (網頁_訪問 (Url))
.子程序 Get_Friend_List, 文本型
.參數 Cookie, 文本型
.參數 BKN, 文本型
.局部變量 Url, 文本型
.局部變量 Post, 文本型
.局部變量 Ret, 文本型
Url ＝ “http://qun.qq.com/cgi-bin/qun_mgr/get_friend_list”
Post ＝ “bkn=” ＋ BKN
Ret ＝ 編碼_Utf8到Ansi (網頁_訪問 (Url, 1, Post, Cookie))
返回 (Ret)

QQ好友導出的代碼

此功能需要加載精易模塊5.6

.版本 2
.支持庫 iext
.支持庫 eExcel2000
.程序集 窗口程序集_啟動窗口
.子程序 __啟動窗口_創建完畢
圖片框1.圖片 ＝ #QQ頭像
.子程序 初始化
.局部變量 Ret, 文本型
.局部變量 Json, 類_json
.局部變量 i1, 整數型
.局部變量 i2, 整數型
.局部變量 Gname, 文本型
.局部變量 Name, 文本型
.局部變量 Uin, 文本型
.局部變量 s, 整數型
超級列表框1.全部刪除 ()
Ret ＝ Get_Friend_List (Cookie_Overall, BKN_Overall)
Json.解析 (Ret)
.計次循環首 (15, i1)
  Gname ＝ Json.取通用屬性 (“result[” ＋ 到文本 (i1 － 1) ＋ “].gname”)
  .如果真 (Gname ＝ “”)
    Gname ＝ “我的好友”
  .如果真結束
  .計次循環首 (Json.成員數 (“result[” ＋ 到文本 (i1 － 1) ＋ “].mems”), i2)
    Name ＝ Json.取通用屬性 (“result[” ＋ 到文本 (i1 － 1) ＋ “].mems[” ＋ 到文本 (i2 － 1) ＋ “].name”)
    Uin ＝ Json.取通用屬性 (“result[” ＋ 到文本 (i1 － 1) ＋ “].mems[” ＋ 到文本 (i2 － 1) ＋ “].uin”)
    s ＝ 超級列表框1.插入表項 (, , , , , )
    超級列表框1.置標題 (s, 0, 到文本 (s ＋ 1))
    超級列表框1.置標題 (s, 1, Uin)
    超級列表框1.置標題 (s, 2, Name)
    超級列表框1.置標題 (s, 3, Gname)
  .計次循環尾 ()
.計次循環尾 ()
.子程序 _按鈕_快速登錄_被單擊
載入 (窗口1, , 假)
.子程序 _按鈕_注銷登錄_被單擊
網頁_清除Cookie (“qun.qq.com”)
Cookie_Overall ＝ “”
BKN_Overall ＝ “”
按鈕_快速登錄.標題 ＝ “快速登錄”
標簽_QQ號碼.標題 ＝ “QQ號碼：未登錄”
圖片框1.圖片 ＝ #QQ頭像
超級列表框1.全部刪除 ()
信息框 (“注銷登錄成功”, 0, )
.子程序 _按鈕_全部選中_被單擊
.局部變量 i, 整數型
.計次循環首 (超級列表框1.取表項數 (), i)
  超級列表框1.置狀態圖片 (i － 1, 1)
.計次循環尾 ()
.子程序 _按鈕_全部不選_被單擊
.局部變量 i, 整數型
.計次循環首 (超級列表框1.取表項數 (), i)
  超級列表框1.置狀態圖片 (i － 1, -1)
.計次循環尾 ()
.子程序 _按鈕_導出全部_被單擊
通用對話框1.初始目錄 ＝ 取運行目錄 ()
通用對話框1.類型 ＝ 1
通用對話框1.默認文件后綴 ＝ “.xls”
通用對話框1.過濾器 ＝ “Excel文件（*.xls）|*.xls|文本文件（*.txt）|*.txt”
通用對話框1.文件名 ＝ 文本_取右邊 (標簽_QQ號碼.標題, “QQ號碼：”)
.如果真 (通用對話框1.打開 ())
  .如果真 (倒找文本 (通用對話框1.文件名, “.xls”, , 假) ≠ -1)
    導出Excel (通用對話框1.文件名, 真)
  .如果真結束
  .如果真 (倒找文本 (通用對話框1.文件名, “.txt”, , 假) ≠ -1)
    導出Txt (通用對話框1.文件名, 真)
  .如果真結束
  信息框 (“保存成功”, 0, )
.如果真結束
.子程序 _按鈕_導出選中_被單擊
通用對話框1.初始目錄 ＝ 取運行目錄 ()
通用對話框1.類型 ＝ 1
通用對話框1.默認文件后綴 ＝ “.xls”
通用對話框1.過濾器 ＝ “Excel文件（*.xls）|*.xls|文本文件（*.txt）|*.txt”
通用對話框1.文件名 ＝ 文本_取右邊 (標簽_QQ號碼.標題, “QQ號碼：”)
.如果真 (通用對話框1.打開 ())
  .如果真 (倒找文本 (通用對話框1.文件名, “.xls”, , 假) ≠ -1)
    導出Excel (通用對話框1.文件名, 假)
  .如果真結束
  .如果真 (倒找文本 (通用對話框1.文件名, “.txt”, , 假) ≠ -1)
    導出Txt (通用對話框1.文件名, 假)
  .如果真結束
  信息框 (“保存成功”, 0, )
.如果真結束
.子程序 導出Txt
.參數 文件名, 文本型
.參數 全部, 邏輯型
.局部變量 i, 整數型
.局部變量 Uin, 文本型
.局部變量 Name, 文本型
.局部變量 Gname, 文本型
.局部變量 Str, 文本型
.如果真 (全部 ＝ 真)
  .計次循環首 (超級列表框1.取表項數 (), i)
    Uin ＝ 超級列表框1.取標題 (i － 1, 1)
    Name ＝ 超級列表框1.取標題 (i － 1, 2)
    Gname ＝ 超級列表框1.取標題 (i － 1, 3)
    Str ＝ Str ＋ Uin ＋ “----” ＋ Name ＋ “----” ＋ Gname ＋ #換行符
  .計次循環尾 ()
.如果真結束
.如果真 (全部 ＝ 假)
  .計次循環首 (超級列表框1.取表項數 (), i)
    .如果真 (超級列表框1.取當前狀態圖片 (i － 1) ＝ 1)
      Uin ＝ 超級列表框1.取標題 (i － 1, 1)
      Name ＝ 超級列表框1.取標題 (i － 1, 2)
      Str ＝ Str ＋ Uin ＋ “----” ＋ Name ＋ “----” ＋ Gname ＋ #換行符
    .如果真結束
  .計次循環尾 ()
.如果真結束
寫到文件 (文件名, 到字節集 (Str))
.子程序 導出Excel
.參數 文件名, 文本型
.參數 全部, 邏輯型
.局部變量 Data_Head, 文本型, , "0"
.局部變量 i1, 整數型
.局部變量 i2
Excel程序1.創建 ()
Excel工作簿1.置程序 (Excel程序1)
Excel工作簿1.激活工作簿 ()
Excel工作簿1.表格序號 ＝ 1
Data_Head ＝ { “QQ號碼”, “QQ昵稱”, “QQ分組” }
.計次循環首 (取數組成員數 (Data_Head), i1)
  Excel工作簿1.首單元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (1)
  Excel工作簿1.尾單元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (1)
  Excel工作簿1.內容格式 ＝ “@”
  Excel工作簿1.內容 ＝ Data_Head [i1]
  Excel工作簿1.列寬 ＝ 20
.計次循環尾 ()
.如果真 (全部 ＝ 真)
  .計次循環首 (超級列表框1.取表項數 (), i2)
    處理事件 ()
    .計次循環首 (取數組成員數 (Data_Head), i1)
      Excel工作簿1.首單元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
      Excel工作簿1.尾單元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
      Excel工作簿1.內容格式 ＝ “@”
      Excel工作簿1.內容 ＝ 超級列表框1.取標題 (i2 － 1, i1)
    .計次循環尾 ()
  .計次循環尾 ()
.如果真結束
.如果真 (全部 ＝ 假)
  .計次循環首 (超級列表框1.取表項數 (), i2)
    .如果真 (超級列表框1.取當前狀態圖片 (i2 － 1) ＝ 1)
      處理事件 ()
      .計次循環首 (取數組成員數 (Data_Head), i1)
        Excel工作簿1.首單元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
        Excel工作簿1.尾單元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
        Excel工作簿1.內容格式 ＝ “@”
        Excel工作簿1.內容 ＝ 超級列表框1.取標題 (i2 － 1, i1)
      .計次循環尾 ()
    .如果真結束
  .計次循環尾 ()
.如果真結束
Excel工作簿1.保存 (文件名)
Excel工作簿1.關閉 ()
Excel工作簿1.釋放 ()
Excel程序1.退出 ()
Excel程序1.釋放 ()
.子程序 __啟動窗口_可否被關閉, 邏輯型
.局部變量 按鈕, 整數型
按鈕 ＝ 信息框 (“是否關閉軟件”, #詢問圖標 ＋ #是否鈕, )
.如果真 (按鈕 ＝ #是鈕)
  結束 ()
.如果真結束
返回 (假)

運行結果：

感謝各位的閱讀！關于“易語言如何獲取網頁端的好友管理頁面信息導出QQ好友”這篇文章就分享到這里了，希望以上內容可以對大家有一定的幫助，讓大家可以學到更多知識，如果覺得文章不錯，可以把它分享出去讓更多的人看到吧！